// FILM KILLER **BETA**
// RENDERS DUST AND SCRATCHES TO BE OVERLAYED OVER FILM IMAGES
// BY PETROS RAITSIDIS (PRAITSIDIS@GMAIL.COM)

void setup() {
  size(480,320);
  background(0);
  smooth();
  frameRate(25);
}

PFont font;

//GLOBAL SWITCHES
boolean showAll = false;
boolean flicker = true;
boolean showVerts = true;
boolean showScratches = true;
boolean showSpeckles = true;
boolean showHairs = true;
boolean outputFrames = false;

//FLICKER
int maxFlickerBrightness = 40;

//VERTICAL SCRATCH SETTINGS
int verts = 5;//HOW MANY SCRATCHES IN THE GROUP
float range = 2; // THE "JUMPINESS" OF THE SCRATCH
float xpos = 300; //INIT X POSITION

//SPECKLE SETTINGS
int speckle = 10;//SPECKLES PER FRAME
int maxSpeckleSize = 3; //  MAX SIZE OF SPECKLE IN PIXELS

//SCRATH SETTINGS
int scratches = 1;//SCRATCHES PER FRAMES
int scratchSize = 50;//SCRATCH HEIGHT

//HAIR SETTINGS
int hairs = 1;//HAIRS PER FRAME
float maxHairSize = 50;// SIZE OF HAIR IN PIXELS

//OUTPUT SETTINGS
int outputSeconds = 1;
String filename = "peter";
String ext = "jpg";

//KEYBOARD CONTROLS
void keyPressed() {
  //FLICKER TOGGLE
  if(key == '1') {
    if(flicker == true) {
      flicker = false;
    }
    else {
      flicker = true;
    }
  }
  //VERTICAL SCRATCH TOGGLE
  if(key == '2') {
    if(showVerts == true) {
      showVerts = false;
    }
    else {
      showVerts = true;
    }
  }
  // SPECKLE TOGGLE
  if(key == '3') {
    if(showSpeckles == true) {
      showSpeckles = false;
    }
    else {
      showSpeckles = true;
    }
  }
  // SCRATCH TOGGLE
  if(key == '4') {
    if(showScratches == true) {
      showScratches = false;
    }
    else {
      showScratches = true;
    }
  }
  // HAIR TOGGLE
  if(key == '5') {
    if(showHairs == true) {
      showHairs = false;
    }
    else {
      showHairs = true;
    }
  }
}

void draw() {
  if(flicker == true) {
    background(random(maxFlickerBrightness));  
  }
  else {
    background(0);
  }
  //VERTICAL SCRATCHES
  if(showVerts == true || showAll == true) {
    for(int i=0;i<verts;i++) {
      xpos+=random(-range,range);//RANDOMIZE POSITION
      xpos = constrain(xpos,0,width);//CONSTRAIN TO THE IMAGE BOUNDS
      strokeWeight(1);
      stroke(255,random(64,128));
      line(xpos+random(-range,range),0,xpos+random(-range,range),height);
    }
  }

  //SPECKLES
  if(showSpeckles == true || showAll == true) {
    for(int i=0;i<speckle;i++) {
      strokeWeight(random(maxSpeckleSize));
      stroke(random(0,255));
      point(random(width),random(height));
    }
  }

  //SCRATCHES
  if(showScratches == true || showAll == true) {
    for(int i=0;i<scratches;i++) {
      strokeWeight(1);
      stroke(random(64,128));
      float x = random(width);
      float y = random(height);
      line(x,y,x,y+random(scratchSize));
    }
  }

  //HAIRS
  if(showHairs == true || showAll == true) {
    for(int i=0;i<hairs;i++) {
      strokeWeight(1);
      noFill();
      stroke(255,random(0,64));//HAIR COLOR
      float x = random(width);
      float y = random(height);
      bezier(x+random(-maxHairSize,maxHairSize),y+random(-maxHairSize,maxHairSize),x-random(-maxHairSize,maxHairSize),y+random(-maxHairSize,maxHairSize),x+random(-maxHairSize,maxHairSize),y+random(-maxHairSize,maxHairSize),x+random(-maxHairSize,maxHairSize),y+random(-maxHairSize,maxHairSize));    
    }
  }

  //OUTPUT
  if(outputFrames == true) {
    if(millis() < outputSeconds*1000) {
      saveFrame("output/" + filename + "_#####." + ext);//SAVE FRAMES TO OUTPUT FOLDER
    }
    else {
      noLoop();//STOP LOOPING WHEN OUTPUT IS DONE
    }
  }

  font = loadFont("ArialMT-11.vlw");
  textFont(font);
  fill(0);
  noStroke();
  rect(0,0,115,95);
  fill(64,168,255);
  String info = "TOGGLES:\n1. Flicker: " + flicker + "\n2. Vert. Scratch: " + showVerts + "\n3. Speckle: " + showSpeckles + "\n4. Scratches: " + showScratches + "\n5. Hairs: " + showHairs + "\nFPS: " + int(frameRate);
  text(info,6,12);
}